home *** CD-ROM | disk | FTP | other *** search
/ The World's Largest Collection of Windows Software / The World's Largest Collection of Windows Software - Disc 1.iso / connect / _b1 / mrun211 / mrun211d.was < prev    next >
Text File  |  1993-05-01  |  24KB  |  795 lines
  1. ;MailRun v2.11:  Part D, adddlfile
  2. ;1992-1993 Gerald P. Sully, all rights reserved.
  3.  
  4. #comment
  5. **************************************************************************
  6. **************************************************************************
  7. * 
  8. * This file contains routines related to adding a "Download File"
  9. * item to a mailrun.  It puts up the Download Files dialog box,
  10. * which displays the contents of the available files index (the
  11. * *.idx file for the BBS).  When a file is selected from the 
  12. * list, a detailed description is displayed from the *.dbf file 
  13. * for the BBS).
  14. * 
  15. * The index may be obtained either through the getnewfiles() 
  16. * procedure, which opens *.QWK files and checks for a newfiles.dat 
  17. * file, or by importing a list from an external source.  In either
  18. * case, the file is parsed by the import() procedure.
  19. * 
  20. **************************************************************************
  21. **************************************************************************
  22. #endcomment
  23.  
  24. #define MRUN211D
  25. #define MRUN211DE
  26.  
  27. #include "MRUN211.h"
  28.  
  29. string DXFileTabs, BBSidx, BBSdbf, DLPurgeLimit, BBSChoice
  30. integer DLSortField
  31.  
  32. #comment
  33. *********************************************************************
  34. * 
  35. * MAIN()
  36. * 
  37. * Calls checkchild(), makebbslist(), makedesc(),
  38. * getlastitem(), clearfiledesc(), getnewfiles(), 
  39. * gettaskstring(), import(), importwarning(), 
  40. * openfile(), dlfilebox(), deldlfile(), insertitem(),
  41. * menudim(), makefullname(), interfaceon(), interfaceoff(),
  42. * sortidx(), purgeoldfiles()
  43. * 
  44. * Adds a GetFile item to the mailrun.
  45. * 
  46. *********************************************************************
  47. #endcomment
  48.  
  49. proc main
  50. string dlfileString, statstring, ImportFile, ImportFilter, char
  51. integer dialogstatus, Perm, j 
  52.     menudim()
  53.     checkchild()
  54.     findfirst MailRun
  55.     MailRunTrunc = $FILENAME
  56.     
  57.     ;Set up variables for the dlfilebox
  58.     DXFileTabs = "58,92,130,305,315,319,322,325,328"
  59.     strextract BBSChoice TaskItem "`t" 3
  60.     strextract char TaskItem "`t" 4
  61.     atoi char j
  62.     profilerd MailRun "MailRun" "DLSortField" DLSortField
  63.     profilerd MailRun "MailRun" "DLPurgeLimit" DLPurgeLimit
  64.     makebbslist()
  65.     FileDesc = makefullname(TempDir, "DESC.TMP")
  66.     BBSdbf = makefullname(MailRunDir, BBSChoice)
  67.     strcat BBSdbf ".DBF"
  68.     BBSidx = makefullname(MailRunDir, BBSChoice)
  69.     strcat BBSidx ".IDX"
  70.     
  71.     ;Update the available files database
  72.     clearfiledesc()
  73.     FileName = ""
  74.     dlfilebox()
  75.     purgeoldfiles()
  76.     getnewfiles()
  77.     updatedlg 16
  78.     dialogstatus = $DIALOG
  79.     while dialogstatus != 1
  80.         switch dialogstatus
  81.             case 10
  82.                 ;User selected "Add"
  83.                 if not NULLSTR FileName
  84.                     ;only add request if a filename has been entered
  85.                     strupr FileName
  86.                     Perm = 2 - PermRadio
  87.                     strfmt dlfileString "1,%d,GetFile,%s,%s" Perm FileName Conf
  88.                     strfmt statstring \
  89.                         "Added to %s:  `"Download %s from Conference %s`"" \
  90.                         BBSChoice FileName Conf
  91.                     ;Update MAILRUN.INI, task list
  92.                     j++
  93.                     insertitem(BBSChoice, j, dlfileString)
  94.                     TaskItem = gettaskstring(BBSChoice, j)
  95.                     statmsg statstring
  96.                 endif
  97.             endcase
  98.             case 11
  99.                 ;User selected "Delete"
  100.                 deldlfile()
  101.                 updatedlg 148
  102.             endcase
  103.             case 12
  104.                 ;User selected "Import"
  105.                 ;allow the user to abort operation if it will take too long
  106.                 if importwarning()
  107.                     ImportFilter = makefullname(MailRunDir, "*.lst")
  108.                     sdlgfopen "Import File List" ImportFilter ImportFile
  109.                     if SUCCESS
  110.                         ;if the user has selected a file to import...
  111.                         interfaceoff()
  112.                         statmsg "Updating database...      0 files added..."
  113.                         import(ImportFile, 0)
  114.                         sortidx(BBSidx, DLSortField)
  115.                         statmsg ""
  116.                         interfaceon()
  117.                         updatedlg 16
  118.                     endif
  119.                 endif
  120.             endcase
  121.             case 13
  122.                 ;User selected "Purge"
  123.  
  124.                 ;Set index and database files to zero length.  Set display file
  125.                 ;to a space character.  The latter is necessary becuase of an 
  126.                 ;ASPECT bug that won't allow update of an ftext box if the 
  127.                 ;displayed file is nonexistent or zero length.
  128.  
  129.                 openfile(BBSidxFile, BBSidx, _CREATE, _NORMAL)
  130.                 openfile(BBSdbfFile, BBSdbf, _CREATE, _NORMAL)
  131.                 fclose BBSidxFile
  132.                 fclose BBSdbfFile
  133.                 clearfiledesc()
  134.                 FileName = ""
  135.                 updatedlg 148
  136.             endcase
  137.             case 50
  138.                 ;User selected a new sort method
  139.                 if checkfile(BBSidx)
  140.                     profilewr MailRun "MailRun" "DLSortField" DLSortField
  141.                     sortidx(BBSidx, DLSortField)
  142.                     updatedlg 16
  143.                 endif
  144.             endcase
  145.             case 130
  146.                 ;User selected a file from the index window
  147.                 strextract FileName FileChoice "`t" 0
  148.                 makedesc(BBSdbf)
  149.                 updatedlg 132
  150.             endcase
  151.             case 170
  152.                 ;User changed BBS with the combobox
  153.                 j = getlastitem(BBSChoice)
  154.                 TaskItem = gettaskstring(BBSChoice, j)
  155.                 ;Update the available files database
  156.                 BBSdbf = makefullname(MailRunDir, BBSChoice)
  157.                 strcat BBSdbf ".DBF"
  158.                 BBSidx = makefullname(MailRunDir, BBSChoice)
  159.                 strcat BBSidx ".IDX"
  160.                 purgeoldfiles()
  161.                 getnewfiles()
  162.                 clearfiledesc()
  163.                 FileName = ""
  164.                 updatedlg -1
  165.             endcase
  166.             case 230
  167.                 clearfiledesc()
  168.                 updatedlg 4
  169.             endcase
  170.         endswitch
  171.         dialogstatus = $DIALOG
  172.     endwhile
  173.     profilewr MailRun "MailRun" "DLPurgeLimit" DLPurgeLimit
  174.     statmsg ""
  175. endproc
  176.  
  177.  
  178. #comment
  179. *********************************************************************
  180. * 
  181. * IMPORTWARNING()
  182. * 
  183. * Called by main()
  184. * 
  185. * If sorting or duplicate filter is set, warns that an
  186. * import operation may take a long time.
  187. * 
  188. *********************************************************************
  189. #endcomment
  190.  
  191. func importwarning : integer
  192. string WarningMsg
  193. integer Response
  194.     if (DLSortField != 1) && NewfileFilter
  195.         WarningMsg = "You have chosen to import a list of files with \
  196. the duplicate file filter and sorting enabled.  With large file \
  197. lists, this may result in very slow performance.`r`n`r`nDo you \
  198. wish to continue?"
  199.     elseif DLSortField != 1
  200.         WarningMsg = "You have chosen to import a list of files with \
  201. sorting enabled.  With large file \
  202. lists, this may result in very slow performance.`r`n`r`nDo you \
  203. wish to continue?"
  204.     elseif NewfileFilter
  205.         WarningMsg = "You have chosen to import a list of files with \
  206. the duplicate file filter enabled.  With large file \
  207. lists, this may result in very slow performance.`r`n`r`nDo you \
  208. wish to continue?"
  209.     else
  210.         return 1
  211.     endif
  212.     sdlgmsgbox "MailRun Message" WarningMsg QUESTION YESNO Response 2
  213.     switch Response
  214.         case 6
  215.             return 1
  216.         endcase
  217.         case 7
  218.             return 0
  219.         endcase
  220.     endswitch
  221. endfunc
  222.  
  223.  
  224. #comment
  225. *********************************************************************
  226. * 
  227. * PURGEOLDFILES()
  228. * 
  229. * Called by main()
  230. * 
  231. * Calls openfile(), interfaceon(), interfaceoff(),
  232. * checkfile(), makefullname()
  233. * 
  234. * Purges aged files from the download database and compresses
  235. * the database.  The current date is checked against each file
  236. * date, and those that are aged are discarded.  The number of
  237. * days a file can be kept is determined by DLPurgeLimit, which
  238. * is set in the Download Files dialog box.
  239. * 
  240. *********************************************************************
  241. #endcomment
  242.  
  243. proc purgeoldfiles
  244. string Oldidx, Olddbf, idxString, PurgeMsg
  245. string DLFileTrunc, FileSize, FileDate, FDesc, DescBegin, DescLength
  246. integer char, count
  247. long DLPurgeDays, counter, OldDate, FD, TD, DB, DL, NDB
  248.     Oldidx = makefullname(TempDir, "oldidx.tmp")
  249.     Olddbf = makefullname(TempDir, "olddbf.tmp")
  250.     if !(checkfile(BBSidx) && checkfile(BBSdbf))
  251.         return
  252.     endif
  253.     findfirst BBSidx
  254.     strsltime $FDATE "00:00:00" FD
  255.     strsltime $DATE "00:00:00" TD
  256.     atol DLPurgeLimit DLPurgeDays
  257.     if DLPurgeDays && (FD < TD)
  258.         statmsg "Purging old files...    Files in database:  0"
  259.         interfaceoff()
  260.         
  261.         ;save the original dates of the database files so that
  262.         ;getnewfiles() can function properly
  263.         getfltime BBSidx OldDate
  264.         
  265.         copyfile BBSidx Oldidx
  266.         copyfile BBSdbf Olddbf
  267.         openfile(OldidxFile, Oldidx, _READWRITE, _TEXT)
  268.         openfile(OlddbfFile, Olddbf, _READWRITE, _NORMAL)
  269.         openfile(BBSidxFile, BBSidx, _CREATE, _TEXT)
  270.         openfile(BBSdbfFile, BBSdbf _CREATE, _NORMAL)
  271.         count = 0
  272.         fgets OldidxFile idxString
  273.         while not feof OldidxFile
  274.             ;loop through the old .idx file
  275.             strextract FileDate idxString "`t" 2
  276.             strsltime FileDate "00:00:00" FD
  277.             if FD < (TD - (DLPurgeDays * 86400))
  278.                 ;if the file is older than allowed, discard it
  279.                 fgets OldidxFile idxString
  280.                 loopwhile
  281.             endif
  282.             count ++
  283.             strfmt PurgeMsg \
  284.                 "Purging old files...    Files in database:  %d" count
  285.             statmsg  PurgeMsg
  286.             strextract DLFileTrunc idxString "`t" 0
  287.             strextract FileSize idxString "`t" 1
  288.             strextract FDesc idxString "`t" 3
  289.             strextract DescBegin idxString "`t" 4
  290.             strextract DescLength idxString "`t" 5
  291.             atol DescBegin DB
  292.             atol DescLength DL
  293.             ftell BBSdbfFile NDB
  294.             ;go to the beginning of the file description
  295.             fseek OlddbfFile DB 0
  296.             ;copy the description to the new .dbf file
  297.             for counter = 1 upto DL
  298.                 fgetc OlddbfFile char
  299.                 fputc BBSdbfFile char
  300.             endfor
  301.             ;add the index line to the new .idx file
  302.             fstrfmt BBSidxFile "%s`t%s`t%s`t%s`t%ld`t%ld`r`n" \
  303.                 DLFileTrunc FileSize FileDate FDesc NDB DL
  304.             fgets OldidxFile idxString
  305.         endwhile
  306.         fclose BBSidxFile
  307.         fclose BBSdbfFile
  308.         fclose OldidxFile
  309.         fclose OlddbfFile
  310.         delfile Oldidx
  311.         delfile Olddbf
  312.         ;restore the original dates of the database files
  313.         setfltime BBSidx OldDate
  314.         setfltime BBSdbf OldDate
  315.         interfaceon()
  316.         statmsg ""
  317.     endif    
  318. endproc
  319.  
  320.  
  321. #comment
  322. *********************************************************************
  323. * 
  324. * GETNEWFILES()
  325. * 
  326. * Called by main()
  327. * 
  328. * Calls openfile(), interfaceon(), interfaceoff(), checkfile()
  329. * makefullname(), import(), sortidx(), findstring()
  330. * 
  331. * Extracts NEWFILES.DAT from a BBS .QWK packet.  This is
  332. * used to update an index file, BBS.IDX, and a database of
  333. * descriptions, BBS.DBF, where "BBS" is the BBS ID.  The
  334. * first line of each file description in NEWFILES.DAT is
  335. * converted to a tab delimited string containing the file's
  336. * name, size, date and partial description.  The starting
  337. * point of the full description in the database and the
  338. * length of the description are appended and the entire
  339. * string is appended to the index file.  Tabstops in the
  340. * index flistbox in dlfilebox() allow push the index and
  341. * length beyond the right edge of the box.  The full
  342. * description of each file is appended to the database file.
  343. * 
  344. *********************************************************************
  345. #endcomment
  346.  
  347. proc getnewfiles
  348. string QWKFile, NewFiles, MailDir, QWKArchiver
  349. string FPCmdLine, MRUnarcBat, Drive
  350. integer ArcId, WinId, FirstPass, NumFiles
  351. integer i, n
  352. long QWKTime, IDXTime
  353.     profilerd MailRun "MailRun" "MailDir" MailDir
  354.     profilerd MailRun BBSChoice "QWKArchiver" QWKArchiver
  355.     QWKFile = makefullname(MailDir, BBSChoice)
  356.     strcat QWKFile ".QWK"
  357.  
  358.     ;Only update the database if there is a more recent
  359.     ;QWK file for the BBS
  360.  
  361.     if isfile QWKFile
  362.         getfltime QWKFile QWKTime
  363.     else
  364.         QWKTime = 0
  365.     endif
  366.  
  367.     if checkfile(BBSidx) && checkfile(BBSdbf)
  368.         ;if both database files exist, get their time stamps
  369.         getfltime BBSidx IDXTime
  370.     else
  371.         IDXTime = 0
  372.     endif
  373.     
  374.     profilerd MailRun "MailRun" "SavePackets" n
  375.     profilerd MailRun "MailRun" "NewfileFilter" NewfileFilter
  376.     FirstPass = 1
  377.     NumFiles = 0
  378.     i = 0
  379.     interfaceoff()
  380.     while (QWKTime > IDXTime) && (i <= n)
  381.         if FirstPass
  382.             statmsg "Updating database...      0 files added..."
  383.             FirstPass = 0
  384.         endif
  385.  
  386.         ;Set up the unarchive command string and run it.
  387.  
  388.         NewFiles = makefullname(TempDir, "NEWFILES.DAT")
  389.         if isfile NewFiles
  390.             delfile NewFiles
  391.         endif
  392.         if strcmpi QWKArchiver "FPZIPX.EXE"
  393.             ;if the QWK archiver is FlashPoint ZIP (Windows-based)...
  394.             strfmt FPCmdLine "fpzipx.exe -e %s %s NEWFILES.DAT" QWKFile TempDir
  395.             run FPCmdLine MINIMIZED ArcId
  396.             taskwin ArcId WinId
  397.             ;stall until execution is finished
  398.             while !(findstring($TITLEBAR, "FlashPoint")) || (WinId == $ACTIVEWIN)
  399.             endwhile
  400.             exittask ArcId
  401.         else
  402.             ;otherwise, create a batch file and run it
  403.             MRUnarcBat = makefullname(TempDir, "MRUnarc.BAT")
  404.             openfile(MRUnarcFile, MRUnarcBat, _CREATE, _NORMAL)
  405.             substr Drive TempDir 0 2
  406.             fstrfmt MRunarcFile "%s`r`ncd %s`r`n" Drive TempDir
  407.             switch QWKArchiver
  408.                 case "ARJ.EXE"
  409.                 case "LHA.EXE"
  410.                 case "LHARC.EXE"
  411.                     fstrfmt MRUnarcFile "%s e %s NEWFILES.DAT`r`n" \
  412.                         QWKArchiver QWKFile
  413.                 endcase
  414.                 case "PKUNZIP.EXE"
  415.                 case "PKXARC.EXE"
  416.                     fstrfmt MRUnarcFile "%s %s NEWFILES.DAT`r`n" \
  417.                         QWKArchiver QWKFile
  418.                 endcase
  419.                 case "ZOO.EXE"
  420.                     fstrfmt MRUnarcFile "%s -extract NEWFILES.DAT" \
  421.                         QWKArchiver QWKFile
  422.                 endcase
  423.             endswitch
  424.             fclose MRUnarcFile
  425.             run MRUnarcBat MINIMIZED ArcId
  426.             ;Stall the script until unzipping is complete
  427.             while istask ArcId
  428.             endwhile
  429.         endif
  430.         import(NewFiles, &NumFiles)
  431.         QWKFile = makefullname(MailDir, BBSChoice)
  432.         strfmt QWKFile "%s.QW%d" QWKFile i
  433.         if isfile QWKFile
  434.             getfltime QWKFile QWKTime
  435.         else
  436.             QWKTime = 0
  437.         endif
  438.         i++
  439.     endwhile
  440.     if NumFiles
  441.         sortidx(BBSidx, DLSortField)
  442.     endif
  443.     setfltime BBSidx $LTIME
  444.     setfltime BBSdbf $LTIME
  445.     interfaceon()
  446.     statmsg ""
  447. endproc
  448.  
  449.  
  450. #comment
  451. *********************************************************************
  452. * 
  453. * IMPORT()
  454. * 
  455. * Called by main(), getnewfiles()
  456. * 
  457. * Calls openfile(), checkfile(), checknfstring(), findstring()
  458. * 
  459. * Imports a file list into the download files database.
  460. * Assumes the format is that appropriate for the BBS type
  461. * for the current BBS.
  462. * 
  463. *********************************************************************
  464. #endcomment
  465.  
  466. proc import
  467. strparm NewFiles
  468. intparm NumFiles
  469. string UpdateMsg
  470. string NewFileString, NewFileName
  471. string FileDate, FileSize, NewFileDate, NewFileSize
  472. string idxFile, idxString
  473. string Month, Day, Year, ThisYear
  474. string dbfString
  475. integer MM, DD, YY, TY
  476. integer inidx
  477. integer NewFileLength
  478. long dbfIndex, dbfLength
  479.     ;make sure the file exists before opening it
  480.     if isfile NewFiles
  481.         openfile(NewFilesFile, NewFiles, _READWRITE, _TEXT)
  482.         if checkfile(BBSidx) && checkfile(BBSdbf)
  483.             ;If both the index and database files exist, open them
  484.             openfile(BBSidxFile, BBSidx, _READWRITE, _NORMAL)
  485.             openfile(BBSdbfFile, BBSdbf, _READWRITE, _NORMAL)
  486.         else
  487.             ;If either the index or database file is missing, start from scratch
  488.             openfile(BBSidxFile, BBSidx, _CREATE, _NORMAL)
  489.             openfile(BBSdbfFile, BBSdbf, _CREATE, _NORMAL)
  490.         endif
  491.         ;Go to the end of the description database
  492.         fseek BBSdbfFile 0 2
  493.  
  494.         ;Loop through each line of the file list checking for a valid date
  495.         ;in the position appropriate for the current BBS type.  If one is
  496.         ;found, it can be assumed this is the first line of a file
  497.         ;description.  Files older than 1980 and post-dated files are
  498.         ;ignored.
  499.  
  500.         fgets NewFilesFile NewFileString
  501.         while not feof NewFilesFile
  502.             ;loop through the file
  503.             profilerd MailRun BBSChoice "BBSType" BBSType
  504.             if findstring(BBSType, "PCBoard") || findstring(BBSType, "RBBS")
  505.                 substr Month NewFileString 23 2
  506.                 substr Day NewFileString 26 2
  507.                 substr Year NewFileString 29 2
  508.             elseif findstring(BBSType, "WildCat")
  509.                 substr Month NewFileString 24 2
  510.                 substr Day NewFileString 27 2
  511.                 substr Year NewFileString 30 2
  512.             elseif findstring(BBSType "Auntie")
  513.                 substr Month NewFileString 21 2
  514.                 substr Day NewFileString 24 2
  515.                 substr Year NewFileString 27 2
  516.             endif
  517.             atoi Month MM
  518.             atoi Day DD
  519.             atoi Year YY
  520.             ThisYear = $DATE
  521.             strdelete ThisYear 0 6
  522.             atoi ThisYear TY
  523.             if (MM >= 1 && MM <= 12) && (DD >= 1 && DD <= 31) && \
  524.                 (YY >= 80 && YY <= TY)
  525.                 ;If there is a valid date in the correct position...
  526.                 ;Put in tab separators
  527.                 strupdt NewFileString "`t" 12 1
  528.                 if findstring(BBSType, "PCBoard") || findstring(BBSType, "RBBS")
  529.                     strupdt NewFileString "`t" 21 1
  530.                     strupdt NewFileString "`t" 31 1
  531.                 elseif findstring(BBSType, "WildCat")
  532.                     strupdt NewFileString "`t" 21 1
  533.                     strupdt NewFileString "`t" 32 1
  534.                     strdelete NewFileString  33 1
  535.                 elseif findstring(BBSType, "Auntie")
  536.                     strupdt NewFileString "`t" 20 1
  537.                     strupdt NewFileString "`t" 29 1
  538.                 endif
  539.                 
  540.                 ;Strip extra spaces
  541.                 strfind NewFileString "`t "
  542.                 while FOUND
  543.                     strreplace NewFileString "`t " "`t"
  544.                     strfind NewFileString "`t "
  545.                 endwhile
  546.                 strfind NewFileString " `t"
  547.                 while FOUND
  548.                     strreplace NewFileString " `t" "`t"
  549.                     strfind NewFileString " `t"
  550.                 endwhile
  551.                 
  552.                 if findstring(BBSType, "WildCat")
  553.                     ;remove commas from file size
  554.                     strextract FileSize NewFileString "`t" 1
  555.                     NewFileSize = FileSize
  556.                     strreplace NewFileSize "," ""
  557.                     strreplace NewFileString FileSize NewFileSize 1
  558.                 else            
  559.                     ;change date format from MM-DD-YY to MM/DD/YY
  560.                     strextract FileDate NewFileSTring "`t" 2
  561.                     NewFileDate = FileDate
  562.                     strreplace NewFileDate "-" "/"
  563.                     strreplace NewFileString FileDate NewFileDate 1
  564.                     if strfind BBSType, "Auntie"
  565.                         strextract FileDate NewFileString "`t" 0
  566.                         NewFileDate = FileDate
  567.                         strreplace NewFileDate " " "." 1
  568.                         strfind NewFileDate ". "
  569.                         while FOUND
  570.                             strreplace NewFileDate ". " "."
  571.                             strfind NewFileDate ". "
  572.                         endwhile
  573.                         strreplace NewFileString FileDate NewFileDate 1
  574.                     endif
  575.                 endif
  576.                 strextract NewFileName NewFileString "`t" 0
  577.                 if NewfileFilter
  578.                     ;If the newfile filter is turned on...
  579.                     inidx = 0
  580.                     rewind BBSidxFile
  581.                     fgets BBSidxFile idxString
  582.                     while not feof BBSidxFile
  583.                         ;Check the filename against each file in the index
  584.                         strextract idxFile idxString "`t" 0
  585.                         if strcmpi idxFile NewFileName
  586.                             inidx = 1
  587.                             exitwhile
  588.                         endif
  589.                         fgets BBSidxFile idxString
  590.                     endwhile
  591.                     if inidx
  592.                         ;If the file is in the index, drop it
  593.                         fgets NewFilesFile NewFileString
  594.                         loopwhile
  595.                     endif
  596.                 endif
  597.                 fseek BBSidxFile 0 2
  598.                 NumFiles++
  599.                 strfmt UpdateMsg \
  600.                     "Updating database...      %d files added...      %s" \
  601.                     NumFiles NewFileName
  602.                 statmsg UpdateMsg
  603.                 strlwr NewFileName
  604.                 strlen NewFileName NewFileLength
  605.                 strupdt NewFileString NewFileName 0 NewFileLength
  606.                 ;Append the index
  607.                 ftell BBSdbfFile dbfIndex
  608.                 strfmt NewFileString "%s`t%ld" NewFileString dbfIndex
  609.                 fputs BBSidxFile NewFileString
  610.                 ;Get the first line of the description and put it in
  611.                 ;the database
  612.                 strextract dbfString NewFileString "`t" 3
  613.                 fputs BBSdbfFile dbfString
  614.                 ;Auntie lists have a blank line before the description
  615.                 if strfind BBSType "Auntie"
  616.                     fgets NewFilesFile NewFileString
  617.                 endif
  618.                 fgets NewFilesFile NewFileString
  619.                 ;Get remaining lines of description
  620.                 while checknfstring(&NewFileString)
  621.                     fstrfmt BBSdbfFile " %s" NewFileString
  622.                     fgets NewFilesFile NewFileString
  623.                 endwhile
  624.                     
  625.                 ;Find the length of the description and append to the index file
  626.  
  627.                 ftell BBSdbfFile dbfLength
  628.                 dbfLength -= dbfIndex
  629.                 fstrfmt BBSidxFile "`t%ld" dbfLength
  630.                 fputs BBSidxFile "`r`n"
  631.             else
  632.                 ;If this isn't a file description, get the next line
  633.                 fgets NewFilesFile NewFileString
  634.             endif
  635.         endwhile
  636.         fclose NewFilesFile
  637.         fclose BBSidxFile
  638.         fclose BBSdbfFile
  639.     endif
  640. endproc
  641.  
  642.  
  643. #comment
  644. *********************************************************************
  645. * 
  646. * CHECKNFSTRING()
  647. * 
  648. * Called by import()
  649. * 
  650. * Checks a string for the format appropriate for a
  651. * description line.  If it is a proper description line
  652. * the line is formatted and a value of 1 is returned.
  653. * If it is not proper, a value of 0 is returned.
  654. * 
  655. *********************************************************************
  656. #endcomment
  657.  
  658. func checknfstring : integer
  659. strparm NewFileString
  660. string Blanks
  661. integer i
  662.     if strfind BBSType "PCBoard"
  663.         strset blanks ' ' 33
  664.         if rstrcmp blanks NewFileString 33
  665.             strdelete NewFileString 0 33
  666.             return 1
  667.         endif
  668.     elseif strfind BBSType "WildCat"
  669.         strpeek NewFileString 33 i
  670.         if i == '|'
  671.             strdelete NewFileString 0 35
  672.             return 1
  673.         endif
  674.     elseif strfind BBSType "Auntie"
  675.         strset blanks ' ' 9
  676.         if rstrcmp blanks NewFileString 9
  677.             strdelete NewFileString 0 9
  678.             return 1
  679.         endif
  680.     endif
  681.     return 0
  682. endfunc
  683.  
  684.  
  685. #comment
  686. *********************************************************************
  687. * 
  688. * DELDLFILE()
  689. * 
  690. * Called by main()
  691. * 
  692. * Calls openfile(), interfaceon(), interfaceoff(),
  693. * makefullname(), makedesc(), clearfiledesc()
  694. * 
  695. * Deletes a file from the BBS's download index and selects
  696. * the next file in the list.
  697. * 
  698. *********************************************************************
  699. #endcomment
  700.  
  701. proc deldlfile
  702. string OldBBSidx, idxFile, idxString, temp
  703.     interfaceoff()
  704.     OldBBSidx = makefullname(TempDir, "OLIDX.TMP")
  705.     copyfile BBSidx OldBBSidx
  706.     openfile(OldidxFile, OldBBSidx, _READWRITE, _TEXT)
  707.     openfile(BBSidxFile, BBSidx, _CREATE, _TEXT)
  708.     fgets OldidxFile idxString
  709.     while not feof OldidxFile
  710.         strextract idxFile idxString "`t" 0
  711.         if strcmpi idxFile FileName
  712.             exitwhile
  713.         endif
  714.         fputs BBSidxFile idxString
  715.         fgets OldidxFile idxString
  716.     endwhile
  717.     fgets OldidxFile idxString
  718.     FileChoice = idxString
  719.     while not feof OldidxFile
  720.         fputs BBSidxFile idxString
  721.         fgets OldidxFile idxString
  722.     endwhile
  723.     if NULLSTR FileChoice
  724.         fseek BBSidxFile -100 2
  725.         fgets BBSidxFile temp
  726.         while not NULLSTR temp
  727.             FileChoice = temp
  728.             fgets BBSidxFile temp
  729.         endwhile
  730.     endif
  731.     fclose BBSidxFile
  732.     fclose OldidxFile
  733.     if not NULLSTR FileChoice
  734.         strextract FileName FileChoice "`t" 0
  735.         makedesc(BBSdbf)
  736.     else
  737.         clearfiledesc()
  738.         FileName = ""
  739.     endif
  740.     interfaceon()
  741. endproc
  742.  
  743.  
  744. #comment
  745. *********************************************************************
  746. * 
  747. * DLFILEBOX()
  748. * 
  749. * Called by main()
  750. * 
  751. * Displays the Download Files dialog box.
  752. * 
  753. *********************************************************************
  754. #endcomment
  755.  
  756. proc dlfilebox
  757. PermRadio = 2
  758. Conf = "0"
  759. destroydlg
  760. HelpPage = 9
  761. dialogbox 19 38 324 201 15 "Download Files" helpid HelpPage
  762.    text  12 27 56 8 left "Filename"
  763.    text  70 27 40 8 left "Size"
  764.    text  104 27 34 8 left "Date"
  765.    text  142 27 117 8 left "Description"
  766.    flistbox 12 38 300 50 BBSidx DXFileTabs single FileChoice
  767.    groupbox 12 89 300 17
  768.    radiobutton 26 94 60 11 "Unsorted" DLSortField
  769.    radiobutton 91 94 67 11 "Sort by Name" 
  770.    radiobutton 172 94 61 11 "Sort by Size" 
  771.    radiobutton 241 94 62 11 "Sort by Date" endgroup
  772.    text  13 112 49 8 left "Filename:"
  773.    editbox 12 122 101 12 FileName
  774.    text  129 112 67 8 left "Description:"
  775.    ftext 129 122 182 50 FileDesc
  776.    text  13 141 56 8 right "Purge files after"
  777.    text  96 141 16 8 left "days"
  778.    editbox 74 139 16 12 DLPurgeLimit
  779.    text  14 158 78 8 right "D/L from Conference:"
  780.    editbox 96 156 16 12 Conf
  781.    radiobutton 12 178 53 13 "Permanent" PermRadio
  782.    radiobutton 70 178 54 13 "Temporary" endgroup
  783.    pushbutton 130 179 30 14 "&Add" normal default
  784.    pushbutton 168 179 30 14 "De&lete" normal
  785.    pushbutton 206 179 30 14 "&Import" normal
  786.    pushbutton 244 179 30 14 "&Purge" normal
  787.    pushbutton 282 179 30 14 "&Done" cancel
  788.    text  76 9 80 8 right "Download File from:"
  789.    combobox 160 7 70 42 BBSList BBSChoice sort
  790. enddialog
  791. endproc
  792.  
  793.  
  794.  
  795.